#!/usr/bin/nu

# slug pattern:
# {thing}-{location}-{kopia|zfs}

# TODO:
# add the rest of the jobs
# run-all command
# create checks implementation to use management API to create each one

let b2Repo = "/home/jbrechtel/kopia/leonard-brechtel-backup/repository.config"
let rootURL = "https://status.roo.lol"
let pingKey = "pRybo-Yjebna0KHQCYCpTg"

let jobs = [{ statusSlug: "photos-content-b2-kopia", type: "kopia", source: "/nas1/photos.roo.lol", target: $b2Repo, }
           ,{ statusSlug: "photos-service-b2-kopia", type: "kopia", source: "/services/photos.roo.lol", target: $b2Repo, }
           ,{ statusSlug: "network-fileshare-b2-kopia", type: "kopia", source: "/nas/files", target: $b2Repo, }
           ,{ statusSlug: "vaultwarden-b2-kopia", type: "kopia", source: "/services/passwords.roo.lol", target: $b2Repo, }
           ,{ statusSlug: "paperless-b2-kopia", type: "kopia", source: "/services/paperless.roo.lol", target: $b2Repo, }
           ,{ statusSlug: "caddy-b2-kopia", type: "kopia", source: "/services/caddy", target: $b2Repo, }
           ,{ statusSlug: "kitchen-b2-kopia", type: "kopia", source: "/services/kitchen.roo.lol", target: $b2Repo, }
           ,{ statusSlug: "ha-backups-b2-kopia", type: "kopia", source: "/services/ha.roo.lol/config/backups", target: $b2Repo, }
           ,{ statusSlug: "zendo-home-azul-zfs", type: "zfs", source: "backups@zendo.brechtel:rpool/home", target: "backups@azul:dune/backups/zendo/home"}
           ,{ statusSlug: "zendo-flipstone-azul-zfs", type: "zfs", source:"backups@zendo.brechtel:rpool/work/flipstone", target:"backups@azul:dune/backups/zendo/flipstone" } 
           ,{ statusSlug: "zendo-root-azul-zfs", type: "zfs", source:"backups@zendo.brechtel:rpool/root", target:"backups@azul:dune/backups/zendo/root" } 
#          ,{ statusSlug: "splendor-home-azul-zfs", type: "zfs", source:"backups@splendor.brechtel:zpcachyos/ROOT/cos/home", target:"backups@azul:dune/backups/splendor/home" } 
#          ,{ statusSlug: "splendor-root-azul-zfs", type: "zfs", source:"backups@splendor.brechtel:zpcachyos/ROOT/cos/root", target:"backups@azul:dune/backups/splendor/root" } 
           ,{ statusSlug: "pandemic-services-azul-zfs", type: "zfs", source:"backups@pandemic.brechtel:primary/services", target:"backups@azul:dune/backups/pandemic/services" } 
           ,{ statusSlug: "photos-content-azul-zfs", type: "zfs", source:"backups@pandemic:nas1/photos.roo.lol", target:"backups@azul:dune/backups/photos.roo.lol" } 
           ,{ statusSlug: "network-fileshare-azul-zfs", type: "zfs", source:"backups@pandemic:nas1/files", target:"backups@azul:dune/backups/files" } 
           ,{ statusSlug: "pandemic-maggie-kopia-azul-zfs", type: "zfs", source:"backups@pandemic:nas1/maggie-kopia", target:"backups@azul:dune/backups/maggie-kopia" } 
           ,{ statusSlug: "pandemic-maggie-azul-zfs", type: "zfs", source:"backups@pandemic:nas1/maggie", target:"backups@azul:dune/backups/files/maggie" } 
	   ]

def backup [job] {
  if $job.type == "kopia" {
    kopiaBackup $job
  } else if $job.type == "zfs" {
    zfsBackup $job
  } else {
    print $"Invalid job type: " + $job.type
  }
}

def zfsBackup [job] {
  logStartJob $job.statusSlug
  try {
    syncoid --no-sync-snap --create-bookmark --no-privilege-elevation --recursive ($job.source) ($job.target)
    logFinishedJob $job.statusSlug
  } catch { |err|
    logFailedJob $job.statusSlug $err.debug
  }
}

def kopiaBackup [job] {
  #using sudo is annoying but since this is backing up docker containers
  #the permissions are often wrong. I should be using podman + rootless
  logStartJob $job.statusSlug
  try {
    sudo kopia --config-file=($job.target) snapshot create ($job.source)
    logFinishedJob $job.statusSlug
  } catch { |err|
    logFailedJob $job.statusSlug $err.debug
  }
}

def logStartJob [slug] {
  print $"starting job: ($slug)"
  print $"($rootURL)/ping/($pingKey)/($slug)/start"
  curl -s $"($rootURL)/ping/($pingKey)/($slug)/start" | save -f /dev/null
}
 
def logFailedJob [slug, err] {
  print $"failed to run job: ($slug) with error: ($err)"
  curl -s $"($rootURL)/ping/($pingKey)/($slug)/fail" | save -f /dev/null
}

def logFinishedJob [slug] {
  print $"finished job: ($slug)"
  curl -s $"($rootURL)/ping/($pingKey)/($slug)" | save -f /dev/null
}

def createJob [job] {
  let jobDetails = { name: $job.statusSlug, slug: $job.statusSlug, timeout: 86400 }
  http post --full --headers {"X-API-Key": $env.HC_API } --content-type "application/json" $"($rootURL)/api/v3/checks/" ($jobDetails | to json)
}

def "main list" [] {
  print "Known jobs:"
  print $"($jobs | get statusSlug | to text)"
}

def "main create-missing" [] {
  let existingSlugs = (curl -H $"X-API-Key: ($env.HC_API)" $"($rootURL)/api/v3/checks/" | from json | get checks.slug | to nuon)
  let missingJobs = $jobs | filter { |job| not ($job.statusSlug in $existingSlugs) }
  $missingJobs | each { createJob $in }
}

def "main run-all" [] {
  $jobs | each { backup $in }
}
 
def main [statusSlug] {
  let matches = $jobs | where statusSlug == $statusSlug
  if ($matches | length) == 1 {
    backup ($matches | first)
  } else {
    print $"Did not find exactly one match for ($statusSlug)"
    exit 1
  }
}

#sudo kopia --config-file=/home/jbrechtel/kopia/leonard-brechtel-backup/repository.config snapshot create /nas1/photos.roo.lol
#sudo kopia --config-file=/home/jbrechtel/kopia/leonard-brechtel-backup/repository.config snapshot create /services/photos.roo.lol
#sudo kopia --config-file=/home/jbrechtel/kopia/leonard-brechtel-backup/repository.config snapshot create /nas/files
#sudo kopia --config-file=/home/jbrechtel/kopia/leonard-brechtel-backup/repository.config snapshot create /services/passwords.roo.lol
#sudo kopia --config-file=/home/jbrechtel/kopia/leonard-brechtel-backup/repository.config snapshot create /services/paperless.roo.lol
#sudo kopia --config-file=/home/jbrechtel/kopia/leonard-brechtel-backup/repository.config snapshot create /services/caddy
#sudo kopia --config-file=/home/jbrechtel/kopia/leonard-brechtel-backup/repository.config snapshot create /services/kitchen.roo.lol
#sudo kopia --config-file=/home/jbrechtel/kopia/leonard-brechtel-backup/repository.config snapshot create /services/ha.roo.lol/config/backups